home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1992 June: ROMin Holiday / ADC Developer CD (1992-06) (''ROMin Holiday'')_iso / Developer Connection - 06-1992.iso / Development Platforms / Apple II / System Software (8-bit) / Disk Images / ProDOS Users Disk / MOIRE.bas < prev    next >
Encoding:
BASIC Source File  |  1983-10-15  |  1.3 KB  |  37 lines
  1. 100  REM  MOIRE PROGRAM
  2. 110  REM 
  3. 110  ONERR  GOTO 370
  4. 130  HOME : VTAB 24
  5. 140  HGR : REM   SET HI-RES GRAPHICS
  6. 150 A =  RND(1) *279: REM  PICK AN X FOR CENTER
  7. 160 B =  RND(1) *159: REM  PICK A Y FOR "CENTER"
  8. 170 N =  INT( RND(1) *7) +2: REM    PICK A STEP SIZE  
  9. 180  PRINT : PRINT : PRINT 
  10. 190  HTAB 10: PRINT "MOIRE PICTURE"
  11. 200  FOR X = 0 TO 278  STEP N: REM STEP THRU A VALUES
  12. 210  IF  PEEK(49152) >127  THEN  GOTO 400
  13. 220  FOR S = 0 TO 1: REM  2 LINES,FROM X AND X+1
  14. 230  HCOLOR= 7 *S: REM  FIRST LINE BLACK, NEXT WHITE
  15. 240  REM  DRAW LINE THRU "CENTER" TO OPPOSITE SIDE
  16. 250  HPLOT X +S,0 TO A,B TO 279 -X -S,159
  17. 260  NEXT S,X
  18. 270  FOR Y = 0 TO 158  STEP N: REM  STEP THRU B VALUES
  19. 280  FOR S = 0 TO 1: REM   2 LINES, FROM Y AND Y+1
  20. 290  HCOLOR= 7 *S: REM  FIRST LINE BLACK, NEXT WHITE
  21. 300  REM  DRAW LINE THRU "CENTER" TO OPPOSITE SIDE
  22. 310  HPLOT 279,Y +S TO A,B TO 0,159 -Y -S
  23. 320  NEXT S,Y
  24. 330  FOR PAUSE = 1 TO 300: REM     DELAY LOOP 
  25. 340  IF  PEEK(49152) >127  THEN  GOTO 400
  26. 350  NEXT PAUSE
  27. 360  GOTO 140: REM  DRAW A NEW PATTERN
  28. 370  REM 
  29. 380  REM  EXIT ROUTINE
  30. 390  REM 
  31. 400  POKE 49168,0: REM  CLEAR KEY CHECK
  32. 410  PRINT : PRINT "MOIRE": PRINT "DEMONSTRATION FINISHED"
  33. 420  PRINT "PRESS 'RETURN' TO EXIT ";
  34. 430  INPUT "";A$
  35. 440  HOME : TEXT 
  36. 450  PRINT "MOIRE": PRINT "DEMONSTRATION FINISHED"
  37. 460  END